/^Zyklus        : / {
	file = FILENAME;
	next
}	

/^Nummer        : / {
	nr = $3;
	heftfile[nr] = file;
	next;
}

/^Hauptpersonen : / {
	person = $0;
	sub(/^Hauptpersonen[ \t]*: /, "", person);
	n = split(person, persons, /[ \t]*,[ \t]*/);
	for (i = 1; i <= n; i++) {
		person = persons[i];
		if (person == "") continue;
		if (!first[person] || nr < first[person]) {
			first[person] = nr;
		} 
		if (nr > last[person]) {
			last[person] = nr;
		}
		num[person]++;
		heftpers[person "@" nr] = 1;
	}
	inpers = 1;

	next;
}

inpers && /^[ \t]/ {
	person = $0;
	sub(/^[ \t]*/, "", person);
	n = split(person, persons, /[ \t]*,[ \t]*/);
	for (i = 1; i <= n; i++) {
		person = persons[i];
		if (person == "") continue;
		if (!first[person] || nr < first[person]) {
			first[person] = nr;
		} 
		if (nr > last[person]) {
			last[person] = nr;
		}
		num[person]++;
		heftpers[person "@" nr] = 1;
	}

	next;
}

/^[A-Z]/ {
	inpers = 0;

	next;
}

END {
	print "<use file='/include/page.rstl' />"
	print "<page>"
	print "<phead charset='iso-8859-1'>"
	print "<title>hjp: perry rhodan: zusammenfassungen: hauptpersonen</title>"
	print "</phead>"
	print "<pbody>"
	print "    <ul class='menu'>"
	print "      <li><a href='/'>hjp</a>"
	print "	<ul>"
	print "	  <li> <a href='/pr/'>Perry Rhodan</a>"
	print "	    <ul>"
	print "	      <li> <a href='./'>Zusammenfassungen</a>"
	print "	        <ul>"
	print "	          <li class='selected'> <a href='hefte.html'>Zyklen und Titel</a></li>"
	print "	          <li> <a href='autoren.html'>Autoren</a></li>"
	print "	          <li> <a href='personen.html'>Hauptpersonen</a></li>"
	print "	        </ul>"
	print "	      </li>"
	print "	    </ul>"
	print "	  </li>"
	print "	  <li><form action='/search/'><input name='q'/></form></li>"
	print "	</ul>"
	print "      </li>"
	print "    </ul>"
	print "    <div class='content'>"
	print "      <h1>Hauptpersonen</h1>"
	print "<dl>"
	sortcmd = "sort -o pers.sorted";
	for (i in first) {
		print i | sortcmd;
		numaut++
	}
	close(sortcmd);
	for (n = 0; n < numaut; n++) {
	 	getline i < "pers.sorted";
		print "<dt>" i "</dt>";
		printf "<dd>%d Roman%s zwischen %d und %d (%d%%)\n",
			num[i], (num[i] > 1 ? "e" : ""),
			first[i], last[i],
			(num[i] * 100 / (last[i] - first[i] + 1)) + 0.5;
		print "<br/>"
		for (j = first[i]; j <= last[i]; j++) {
			if (heftpers [i "@" j]) {
				printf "<a href=\"%s.html#%d\">%d</a>\n",
					heftfile[j], j, j;
			}
		}
		print "</dd>"
	}
	print "</dl>"
	print "    </div>"
	print "  </pbody>"
	print "</page>"

}